投稿者: Tsutomu　

MT5エキスパートアドバイザー EA03_RSI.mq5

システムの概要

　シグナルには指数移動平均とRSIを使います。
売買戦略は指定時間足の終値（C1)がその時間足のEMAを越え、
かつRSIのシグナルが規定値以上あるいは規定値以下になったときに発生します。
デフォルトの設定では上は80（levh）、下は20（levl）に設定してありますが、
ストラテジテスターで最適化して使います。
システムはRSIの値が80以上に達したとき売りのシグナルが出るようにし、
RSIの値が20以下に達したとき買いのシグナルが出るように設定しています。
そして、ポジションがStopで損切り手仕舞いするか、Takeが実行されるまで待つ戦略です。

　RSI（相対力指数）は、J・ウエルズ・ワイルダー・ジュニアが1980年頃に考案した指標で、
現在では一般的に使われています。当時は自動売買システムなどありませんでしたので、
ワイルダーは毎日電卓で計算しワークシートに記録していたようです。
RSIの使い方として、トレンドの転換点が近いことを示すダイバージェンシーが有名です。　

　EA03_RSI.mq5  のプログラムは下のダウンロードから行ってください。
ソースファイルですので、ダウンロードした後コンパイルが必要です。

ダウンロード

　ソースファイルはExpertsフォルダーに格納します。
Expertsフォルダーの開き方は、メタエディタのナビゲータでExpertsを選択し、
マウスの右ボタンをクリックします。そして「フォルダーを開く」を選択します。
Expertsフォルダーを開いた後、ファイルをコピー＆ペーストします。

　コンパイルすると以下のように表示されます。
'EA03_RSI.mq5' EA03_RSI.mq5 1 1
'Trade.mqh' Trade.mqh 1 1
'Object.mqh' Object.mqh 1 1
'StdLibErr.mqh' StdLibErr.mqh 1 1
'SymbolInfo.mqh' SymbolInfo.mqh 1 1
'OrderInfo.mqh' OrderInfo.mqh 1 1
'HistoryOrderInfo.mqh' HistoryOrderInfo.mqh 1 1
'PositionInfo.mqh' PositionInfo.mqh 1 1
'DealInfo.mqh' DealInfo.mqh 1 1
0 error(s), 0 warning(s), compile time: 17366 msec 1 1

プログラムの変更箇所

　変数設定の追加コードは次のようになります。
input double   levh=80.0;
input double   levl=20.0;
input int      RSI_Period=20;
int RSI_Handle;
double m_rsi[3];

　int OnInit()内の初期設定の追加コードは次のようになります。
RSI_Handle=iRSI(_Symbol,_Period,RSI_Period,PRICE_CLOSE);
if(RSI_Handle==INVALID_HANDLE)
     {
      Print("SIGNAL ERROR2");
      return(INIT_FAILED);
     }

　void OnDeinit(const int reason)内の追加コードは次のようになります。
   IndicatorRelease(RSI_Handle);
   Comment("");

　void OnTick()内の追加コードは次のようになります。
if(CopyBuffer(RSI_Handle,MAIN_LINE,0,3,m_rsi)<0)  return;

　下のコードではlevh以上になったとき、rsi_sig でSELシグナルにします。
levl以下になったときrsi_sig でBUYシグナルにします。
   if(m_rsi[1]>=levh  ) rsi_sig =-1;
   if(m_rsi[1]<=levl  ) rsi_sig = 1;

　下のコードでチャート左上にm_rsi[1]の値を表示します。
   Comment("sig   =  ",m_rsi[1]);

　下のコードはBUYの注文を出す箇所ですが、rsi_sig==1でandの論理式を構成します。
if(Buy_S1 && rsi_sig==1)　

　下のコードはSELの注文を出す箇所ですが、rsi_sig==-1でandの論理式を構成します。　
if(Sell_S1 && rsi_sig==-1)

プログラムコード

  EA03_RSI.mq5  のプログラムコードは以下のようになります。
赤字の部分は変更箇所です。


#property copyright "T.S"
#property link      "http://mt5myprogrammingts.blogspot.com"
#property version   "1.00"
#include <Trade/Trade.mqh>

//--- input parameters
input int      Stop=50;
input int      Take=150;
input int      Magic=1001;
input double   Lots=0.01;
input int      Slipage=10;
input double   levh=80.0;
input double   levl=20.0;
//---------------------------
input int      RSI_Period=20;
input int      MA_Period =3;

int maH,RSI_Handle;
double maV[3];
double m_rsi[3];

double sclose;
int STP,TKP,SL;
//+---------------------------+
// Expert initialization function   
//+---------------------------+
int OnInit()
  {
//---
   maH=iMA(_Symbol,_Period,MA_Period,0,MODE_EMA,PRICE_CLOSE);
   RSI_Handle=iRSI(_Symbol,_Period,RSI_Period,PRICE_CLOSE);
//------ 
   if(maH==INVALID_HANDLE)
     {
      Print("SIGNAL ERROR1");
      return(INIT_FAILED);
     }

   if(RSI_Handle==INVALID_HANDLE)
     {
      Print("SIGNAL ERROR2");
      return(INIT_FAILED);
     }
//---
   STP = Stop;
   TKP = Take;
   SL  = Slipage;
   if(_Digits==5 || _Digits==3) //EURUSD=5

     {
      STP = STP*10;
      TKP = TKP*10;
      SL  = Slipage*10;
     }
//---
   return(INIT_SUCCEEDED);
  }

//+----------------------------+
// Expert deinitialization function     
//+----------------------------+
void OnDeinit(const int reason)
  {
//---
   IndicatorRelease(maH);
   IndicatorRelease(RSI_Handle);
   Comment("");
  }
//+-----------------------------+
// Expert tick function        
//+-----------------------------+
void OnTick()
  {
//------------------------------
   MqlTick l_pr;
   MqlRates mrate[2];
//------------------------------

   if(!SymbolInfoTick(_Symbol,l_pr))
     {
      Print("the latest price  error");
      return;
     }

   if(CopyRates(_Symbol,_Period,0,2,mrate)!=2)
     {
      Print("CopyRates of ",_Symbol," failed, no history");
      return;
     }
//-----

   if(CopyBuffer(maH,0,0,3,maV)<0)  return;

   if(CopyBuffer(RSI_Handle,MAIN_LINE,0,3,m_rsi)<0)  return;
//-----   

   bool Buy_sig =false;
   bool Sell_sig=false;

   if(PositionSelect(_Symbol)==true)
     {
      if(PositionGetInteger(POSITION_TYPE)==POSITION_TYPE_BUY)
        {
         Buy_sig=true;
        }
      else if(PositionGetInteger(POSITION_TYPE)==POSITION_TYPE_SELL)
        {
         Sell_sig=true;
        }
     }

   sclose=mrate[0].close;

   bool Buy_S1=(sclose>maV[1]);

   int rsi_sig = 0;

   if(m_rsi[1]>=levh  ) rsi_sig =-1;
   if(m_rsi[1]<=levl)   rsi_sig = 1;

   Comment("sig   =  ",m_rsi[1]);

   if(Buy_S1 && rsi_sig==1)
     {
      if(Buy_sig)  return;
      if(Sell_sig) return;

      double l= Lots;
      double p=NormalizeDouble(l_pr.ask,_Digits);
      double s = NormalizeDouble(l_pr.bid - STP*_Point,_Digits);
      double t = NormalizeDouble(l_pr.ask + TKP*_Point,_Digits);

      CTrade m_trade;
      m_trade.SetExpertMagicNumber(Magic);
      m_trade.PositionOpen(Symbol(),ORDER_TYPE_BUY,l,p,s,t,"");
     }

   bool Sell_S1=(sclose<maV[1]);

   if(Sell_S1 && rsi_sig==-1)
     {
      if(Sell_sig) return;
      if(Buy_sig)  return;

      double l = Lots;
      double p = NormalizeDouble(l_pr.bid,_Digits);
      double s = NormalizeDouble(l_pr.ask + STP*_Point,_Digits;
      double t = NormalizeDouble(l_pr.bid - TKP*_Point,_Digits);

      CTrade m_trade;
      m_trade.SetExpertMagicNumber(Magic);
      m_trade.PositionOpen(Symbol(),ORDER_TYPE_SELL,l,p,s,t,"");
     }
  }
//END

（注意事項：プログラムはあくまでFX個人投資家の学習のための、
デモ口座によるMQL5売買プログラミングの情報提供を目的としております。
プログラムによる運用結果につきましては、自己責任であることをご了承ください。)

このブログを検索

MQL4　/　Tsutomu

MQL5/MQL4プログラミング言語の使い方

MT5エキスパートアドバイザー EA03_RSI.mq5

システムの概要

プログラムの変更箇所

プログラムコード