システムの概要
今回シグナルに使うMACDは1960年代にジェラルド・アペル氏が考案したものです。
日本名は移動平均収束拡散法です。期間の異なる指数移動平均値の収束・拡散を
トレンドのシグナルとしています。売買シグナルの計算式は次のようになります。
MACD ＝ EMA1 － EMA2
SIG ＝ EMA（MACD） //MACDの指数移動平均
売買シグナル ＝ SIG － MACD
（EMA1は短期の指数移動平均）
（EMA2は長期の指数移動平均）
デフォルトでは短期の期間は12、長期の期間は26、SIG の期間は9です。
しかし、ジェラルド・アペル氏は日足をもとにして使っていますので、
自分で最適化する方が良いでしょう。
売買シグナルがプラスのときBUY、マイナスのときSELLになります。
EM04_MACDは、このシグナルと終値が指数移動平均線をクロスしたときを売買のタイミングとしています。
EM04_MACD.mq5 のプログラムは下のダウンロードから行ってください。
ソースファイルですので、ダウンロードした後コンパイルが必要です。
ダウンロード
ソースファイルはExpertsフォルダーに格納します。
Expertsフォルダーの開き方は、メタエディタのナビゲータでExpertsを選択し、
マウスの右ボタンをクリックします。そして「フォルダーを開く」を選択します。
Expertsフォルダーを開いた後、ファイルをコピー＆ペーストします。
コンパイルすると問題がなければ次のように表示されます。
'EA04_MACD.mq5' 1 1
'Trade.mqh' Trade.mqh 1 1
'Object.mqh' Object.mqh 1 1
'StdLibErr.mqh' StdLibErr.mqh 1 1
'SymbolInfo.mqh' SymbolInfo.mqh 1 1
'OrderInfo.mqh' OrderInfo.mqh 1 1
'HistoryOrderInfo.mqh' HistoryOrderInfo.mqh 1 1
'PositionInfo.mqh' PositionInfo.mqh 1 1
'DealInfo.mqh' DealInfo.mqh 1 1
0 error(s), 0 warning(s), compile time: 23796 msec 1 1
プログラムの変更箇所
コードは以前作ったEMA_EA02.mq5をもとに変更していますが、変更箇所は次のようになります。
追加したコード
input int F_MACD_Period=12;
input int S_MACD_Period=26;
input int sig_Period=9;
int MACD_Handle;
double m_macd[3];
double sig_macd[3];
Int OnInit()内の追加コード
MACD_Handle=iMACD(_Symbol,_Period,F_MACD_Period,S_MACD_Period,sig_Period,
PRICE_CLOSE); （＊「プログラムの変更箇所」の終わりにiMACDの使用方法の説明があります。）
if(MACD_Handle==INVALID_HANDLE)
{
Print("SIGNAL ERROR2");
return(INIT_FAILED);
}
void OnDeinit(const int reason)内の追加コード
IndicatorRelease(MACD_Handle);
void OnTick()内の追加コード
if(CopyBuffer(MACD_Handle,0,0,3,m_macd)<0 ) return;
if(CopyBuffer(MACD_Handle,1,0,3,sig_macd)<0) return;
void OnTick()内の変更したコード
int sig = 0;
if(m_macd[1]> sig_macd[1] ) sig = 1;
if(m_macd[1]<=sig_macd[1] ) sig= -1;
Comment("sig = ",sig_macd[1]-m_macd[1]);
if(Buy_S1 && sig == 1)
if(Sell_S1 && sig == -1)
//-----------------------
iMACDの使用方法
int iMACD(
string symbol,
ENUM_TIMEFRAMES period,
int fast_ema_period,
int slow_ema_period,
int signal_period,
ENUM_APPLIED_PRICE applied_price
);
Symbol:通貨ペア設定（_Symbol）
period：通貨ペアの時間足設定（_Period）
fast_ema_period：短期指数移動平均の期間（F_MACD_Period）
slow_ema_period：長期指数移動平均の期間（S_MACD_Period）
signal_period：MACD指数移動平均の期間（sig_Period）
applied_price ：適用価格（PRICE_CLOSE）
プログラムコード
EA04_MACD.mq5 のプログラムコードは以下のようになります。
赤字の部分は変更箇所です。
#property copyright "T.S"
#property link "http://mt5myprogrammingts.blogspot.com"
#property version "1.00"
#include <Trade/Trade.mqh>
//--- input parameters
input int Stop=50;
input int Take=100;
input int Magic=1001;
input double Lots=0.01;
input int Slipage=10;
//---------------------------
input int MA_Period=10;
input int F_MACD_Period=12;
input int S_MACD_Period=26;
input int sig_Period=9;
int maH;
int MACD_Handle;
double maV[3];
double m_macd[3];
double sig_macd[3];
double sclose;
int STP,TKP,SL;
//+---------------------------+
// Expert initialization function
//+---------------------------+
int OnInit()
{
//---
maH=iMA(_Symbol,_Period,MA_Period,0,MODE_EMA,PRICE_CLOSE);
MACD_Handle=iMACD(_Symbol,_Period,F_MACD_Period,S_MACD_Period,sig_Period,
PRICE_CLOSE);
//--- What if handle returns Invalid Handle
if(maH==INVALID_HANDLE)
{
Print("Indicators error1");
return(INIT_FAILED);
}
if(MACD_Handle==INVALID_HANDLE)
{
Print("SIGNAL ERROR2");
return(INIT_FAILED);
}
//---
STP = Stop;
TKP = Take;
SL = Slipage;
if(_Digits==5 || _Digits==3) //EURUSD=5
{
STP = STP*10;
TKP = TKP*10;
SL = Slipage*10;
}
//---
return(INIT_SUCCEEDED);
}
//+----------------------------+
// Expert deinitialization function
//+----------------------------+
void OnDeinit(const int reason)
{
//---
IndicatorRelease(maH);
IndicatorRelease(MACD_Handle);
Comment("");
}
//+-----------------------------+
// Expert tick function
//+-----------------------------+
void OnTick()
{
//------------------------------
MqlTick l_pr;
MqlRates mrate[2];
//------------------------------
if(!SymbolInfoTick(_Symbol,l_pr))
{
Print("the latest price error");
return;
}
if(CopyRates(_Symbol,_Period,0,2,mrate)!=2)
{
Print("CopyRates of ",_Symbol," failed,no history");
return;
}
//-----
if(CopyBuffer(maH,0,0,3,maV)<0) return;
if(CopyBuffer(MACD_Handle,0,0,3,m_macd)<0) return;
if(CopyBuffer(MACD_Handle,1,0,3,sig_macd)<0) return;
//-----
bool Buy_sig =false;
bool Sell_sig=false;
if(PositionSelect(_Symbol)==true)
{
if(PositionGetInteger(POSITION_TYPE)==POSITION_TYPE_BUY)
{
Buy_sig=true;
}
else if(PositionGetInteger(POSITION_TYPE)==POSITION_TYPE_SELL)
{
Sell_sig=true;
}
}
sclose=mrate[0].close;
bool Buy_S1=(sclose>maV[1]);
int sig=0;
if(m_macd[1]> sig_macd[1]) sig=1;
if(m_macd[1]<=sig_macd[1]) sig=-1;
Comment("sig=",sig_macd[1]-m_macd[1]);
if(Buy_S1 && sig==1)
{
if(Buy_sig) return;
if(Sell_sig) return;
double l= Lots;
double p=NormalizeDouble(l_pr.ask,_Digits);
double s = NormalizeDouble(l_pr.bid - STP*_Point,_Digits);
double t = NormalizeDouble(l_pr.ask + TKP*_Point,_Digits);
CTrade m_trade;
m_trade.SetExpertMagicNumber(Magic);
m_trade.PositionOpen(Symbol(),ORDER_TYPE_BUY,l,p,s,t,"");
}
bool Sell_S1=(sclose<maV[1]);
if(Sell_S1 && sig==-1)
{
if(Sell_sig) return;
if(Buy_sig) return;
double l = Lots;
double p = NormalizeDouble(l_pr.bid,_Digits);
double s = NormalizeDouble(l_pr.ask + STP*_Point,_Digits);
double t = NormalizeDouble(l_pr.bid - TKP*_Point,_Digits);
CTrade m_trade;
m_trade.SetExpertMagicNumber(Magic);
m_trade.PositionOpen(Symbol(),ORDER_TYPE_SELL,l,p,s,t,"");
}
}
//END
（注意事項：プログラムはあくまでFX個人投資家の学習のための、
デモ口座によるMQL5売買プログラミングの情報提供を目的としております。
プログラムによる運用結果につきましては、自己責任であることをご了承ください。
パラメータの設定、最適化は読者自ら行ってください。
リアルトレードではテストしておりません。）